Firefox – Proxy via script batch
jeudi 11 octobre 2012 à 22:51Si toi aussi tu dois souvent activer ou désactiver un proxy sur ton Firefox, tu dois aussi trouver que c’est super lourd. Vu que je n’avais « rien à faire » ce soir, j’ai donc créé pour toi (et moi!) une série de batch te permettant de démarrer Firefox avec diverses configurations proxy… 
Dans ce fichier zip, tu en trouveras d’autres qui te permettront diverses choses comme:
- Simplement assigner un proxy (et lancer Firefox ou pas)
- Simplement désassigner un proxy (et lancer Firefox ou pas)
- Avoir le choix de la config en lançant le batch (et lancer Firefox ou pas)
Voici le code complet du batch principal (nommée « FF_Proxy_CHOIX.bat » dans le Zip):
@echo off
echo ****************************************
echo * PROXY FIREFOX - WWW.PERTURBATEUR.COM *
echo ****************************************
REM // Check si systeme 32 ou 64 bits pour le chemin d acces a program files
Set RegQry=HKLM\Hardware\Description\System\CentralProcessor\0
REG.exe Query %RegQry% | Find /i "x86"
If %ERRORLEVEL% == 0 ( goto X86 ) ELSE ( goto X64 )
:X86
set chemin_firefox="C:\Program Files\Mozilla Firefox\firefox.exe"
goto :SUITE
:X64
set chemin_firefox="C:\Program Files (x86)\Mozilla Firefox\firefox.exe"
:SUITE
REM // Affichage des choix
echo.
echo 1 - Firefox sans proxy
echo 2 - Firefox avec configuration proxy xxx
echo.
REM // Declaration variable choix
set choix=
REM // Affichage a l'ecran avec saisie
set /p choix=Choisir une option svp:
REM // Tests
if /I %choix% EQU 1 (goto :NOPROXY)
if /I %choix% EQU 2 (goto :CONFIG1)
:NOPROXY
cd /D "%APPDATA%\Mozilla\Firefox\Profiles"
cd *.default
set ffile=%cd%
type "%ffile%\prefs.js" | findstr /v "user_pref("network.proxy.type", 1);" >"%ffile%\prefs_.js"
rename "%ffile%\prefs.js" "prefs__.js"
rename "%ffile%\prefs_.js" "prefs.js"
del "%ffile%\prefs__.js"
set ffile=
cd %windir%
goto :FIN
:CONFIG1
cd /D "%APPDATA%\Mozilla\Firefox\Profiles"
cd *.default
set ffile=%cd%
REM // Adresse ou ip de votre proxy
echo user_pref("network.proxy.http", "proxy");>>"%ffile%\prefs.js"
REM // Port de votre proxy
echo user_pref("network.proxy.http_port", 2012);>>"%ffile%\prefs.js"
echo user_pref("network.proxy.type", 1);>>"%ffile%\prefs.js"
set ffile=
cd %windir%
goto :FIN
:FIN
REM // Lance Firefox - Les guillemets avant la variable sont indispensables car dans le cas contraire la console reste ouverte
start "" %chemin_firefox%
exit
Tu pourras modifier à ta guise le batch en ajoutant des configurations…
Content? 
Fichier zip: Télécharger!
Inspirations pour la création des scripts: Ici et là 